Встроенные типы данных VBA

Когда при разработке приложения возникает необходимость в переменной для хранения данных, ее описывают в модуле перед процедурами или в конкретной процедуре. В первом случае переменная будет доступна всем процедурам модуля (как контейнер общего пользования), а если в ее описании применено ключевое слово PUBLIC, то переменную смогут использовать даже процедуры других модулей. Такую переменную называют глобальной. В ней удобно размещать данные, требуемые многим процедурам. Переменная, описанная внутри процедуры, называется локальной – она используется только в этой процедуре, а в других могут быть переменные с таким же именем. Инструкция, содержащая описание переменной, имеет вид.

Dim ИмяПеременной As ТипДанных

Для определения глобальной переменной вместо Dim пишут Public. Пример описания переменных.

Pablic Nprof, X0 As Single, Y0 As Single

Dim I As Integer, J As Integer, Date1 As Date, Date2 As Date, ФИО As String*32

Nprf=40

При описании переменной ФИО, кроме ее имени и типа, указана длина в байтах. Длину назначают для строковых переменных. Если длину не задать, то будет считаться, что строка имеет переменную длину. Такой подход менее экономичен. Для переменной Nprof тип вообще не указан – по умолчанию ей будет назначен тип Variant – это удобно для программиста, но также неэкономично: число в формате Variant занимает 16 байт, а строка – 22 байта плюс по одному байту на каждый символ. Переменная Nprf вообще не определена – сразу используется в инструкции присваивания. Она также имеет тип Variant по умолчанию. Такой стиль «ввода в действие» переменных довольно опасен. Если Nprf – это опечатка, а надо было написать Nprof, то, возможно, что эту ошибку будет нелегко обнаружить. Поэтому VBA позволяет наложить требование на явное описание всех переменных в модуле. Для этого в описательную часть модуля (до процедур) надо включить инструкцию Option Explicit. Если теперь попытаться использовать в тексте процедур необъявленные переменные, VBA сразу обнаружит ошибки.

Имена переменных должны начинаться с буквы и могут иметь любую разумную длину – не больше 255 символов. Имена не должны содержать пробелов и специальных символов: ! # $ % & @.

Иногда имена записывают так: Номер_строки или НомерСтроки. Применение полных имен особенно полезно для глобальных переменных, которые хранят параметры моделируемых объектов и явлений. В компактных процедурах удобнее пользоваться переменными, применяемыми в математике и физике, например: X – координата, M – число строк в матрице или таблице, i – номер очередной строки, N – число столбцов, j – номер текущего столбца, V – скорость, S – путь и т. п. При использовании кратких имен их поясняют в комментариях – см. текст процедуры Mrows в подразделе 10.3.

Кроме возможности явного задания типа переменной, VBA позволяет указать тип переменной неявно, добавив к ее имени символ-указатель:

$ – для типа данных String, например, ФИО$="Иванов И.И.";

% – для данных типа Integer, например, i%=1;

& – для данных типа Long, например, CX&=6510200;

! – для данных типа Single, например, x!=107.315;

# – для данных типа Double, например, Pi#=3.14159;

@ – для данных типа Currency, например, SS@=67920.1252.

Такой подход вряд ли стоит рекомендовать, но иногда он может способствовать наглядности.

Наряду с переменными для хранения данных во время работы приложения используются массивы переменных, или просто массивы. Массив описывается так же, как одиночная переменная, только после имени в скобках указывается еще размерность:

Dim V(1 to 200) As Single, T(1 to 200) As Single, i As Integer.

Так можно описать массивы измеренных значений скорости и времени для примера в разделе 4. При вычислениях i-й элемент массива указывают с помощью индекса:

S = S + (V(i) + V(i+1)) * 0.5 * (T(i+1)-T(i)).

Так можно записать блок 2, изображенный на рис. 4.1.

Если при описании массива размерность задать одним числом, например, V(200), то будет считаться, что нумерация элементов массива начинается с 0 и оканчивается числом 200. Кроме одномерных массивов, используются многомерные. Предположим, что на листе Excel в первом столбце размещены идентификаторы строк, например, Y1,Y2,…,YI,…,YM , а в первой строке – идентификаторы столбцов: X1,X2,…,XJ,…,XN. На пересечении I-й строки и J-го столбца находится элемент aIJ матрицы (рис.10.5).

Рис. 10.5. Размещение матрицы с элементами a(I, J) на листе Excel

В этом примере матрица представляет собой таблицу коэффициентов, позволяющих связать любой YI уравнением со значениями X1,…,XN:

YI=aI1*X1+aI2*X2+…+aIJ*XJ+…+aIN*XN.

Другими словами, мы имеем матричную запись системы линейных уравнений. Пусть для последующей работы с матрицей требуется определить M, N, разместить идентификаторы YI (I=1,…,M) и XJ (J=1,…N) в массивах CY, CX, а элементы матрицы в двумерном массиве A(I,J).

Этот пример иллюстрирует часто встречающуюся ситуацию: в момент составления программы обычно не известно количество элементов массива – оно определяется программой во время исполнения. Если заранее можно оценить максимальную длину массива, то его часто резервируют с расчетом на максимальную размерность. Так, в нашем случае можно принять ограничение: разрабатываемая программа предназначается для работы с матрицами, у которых число строк и столбцов не превышает 40. Тогда инструкция для резервирования массивов будет иметь вид:

Dim CY(1 to 40), CX(1 to 40), A(1 to 40,1 to 40) As Double.

Но Visual Basic предоставляет и другую возможность – динамического переопределения размерности массивов. Рассмотрим следующий модуль.

Option Explicit

Dim CY( ), CX( ), A( ) As Double

Dim I As Integer, J As Integer, M As Integer, N As Integer

Private Sub CommandButton1_Click( )

MNTab 'Определение M, N - размерности матрицы

ReDim CY(1 To M)

ReDim CX(1 To N) 'Изменение размерности массивов

ReDim A(1 To M, 1 To N)

TabCXCY 'Копирование идентификаторов столбцов и строк в массивы CX, CY

TabA 'Копирование матрицы в массив A

End Sub

Private Sub MNTab( )

I = 2: Do Until IsEmpty(Cells(I, 2))

I = I + 1

Loop

M = I - 2 'M - число строк в таблице

J = 2: Do While Not IsEmpty(Cells(2, J))

J = J + 1

Loop

N = J - 2 'N - число столбцов в таблице

End Sub

Private Sub TabCXCY( )

For J = 1 To N

CX(J) = Cells(1, J + 1).Value 'Идентификаторы столбцов

Next J

For I = 1 To M

CY(I) = Cells(I + 1, 1).Value 'Идентификаторы строк

Next I

End Sub

Private Sub TabA( )

For I = 1 To M

For J = 1 To N

A(I, J) = Cells(I + 1, J + 1).Value

Next J

Next I

End Sub

Этот модуль содержит событийную процедуру CommandButton1_Click, решающую поставленную выше задачу при нажатии кнопки на листе Excel (на рис. 10.5 показана только сама матрица, причем символически), и общие процедуры: MNTab – определение числа строк и столбцов матрицы (M и N); TabCXCY – копирование идентификаторов столбцов и строк в массивы CX, CY; TabA – копирование матрицы из таблицы на листе Excel в двумерный массив A.

Массивы CX, CY, A и основные переменные, требуемые для работы с матрицей, определены на уровне модуля, т. е. доступны всем его процедурам. Элементы массивов CX и CY имеют тип VARIANT, так как для них тип явно не указан. Выбор типа VARIANT для этих массивов обусловлен тем, что при последующем расширении написанного модуля в этих массивах, возможно, потребуется размещать не имена строк и столбцов, а сами значения YI и XJ. Обратим внимание на то, что все три массива в начале модуля определены без указания размерности, т. е. как динамические, а в процедуре CommandButton1 _Click наши массивы переопределены – но только после определения M и N с помощью процедуры MNTab. Приведенные процедуры еще пригодятся для пояснения циклов и как пример для самостоятельной разработки процедур в практических работах.

Завершая рассмотрение массивов, заметим, что в математике аналогом программистского термина одномерный массив является понятие вектор. Вектор можно и нужно толковать не только геометрически: в общем случае это набор значений, например, свойств (признаков) объекта. Если представить себе многомерную систему координат, где по каждой оси отложено значение одного из свойств объекта (скажем, длина автомобиля, расход горючего, максимальная скорость и т. д.), то каждый объект в такой системе координат будет точкой – точкой в признаковом пространстве. Совокупность значений отдельных координат (в нашем примере – длины автомобиля, расхода горючего, максимальной скорости и др.) и есть вектор. Понятие вектора очень удобно для краткой записи операций с массивами чисел – см. самостоятельную работу «Операции с матрицей» в конце книги. Кстати, математический термин матрица соответствует двумерному массиву. Матрицу можно рассматривать как совокупность векторов – строк или столбцов.

Теперь рассмотрим конструирование собственных типов данных. Например, для хранения записей о книгах определим в начале модуля тип данных RecBook с помощью инструкции.

Type RecBook

Название As String*50

Автор As String*20

Издательство As String*16

Год As Integer

End Type

Теперь в этом же модуле или в одной из его процедур зарезервируем массив для хранения записей о книгах.

Dim Books(500) As RecBook

Для доступа к полям Издательство и Год в i-й записи массива воспользуемся инструкциями.

Books(i).Издательство="Недра" : Books(i).Год=1999

В этой книге мы намеренно пользуемся примерами, а не строгими определениями синтаксиса инструкций VBA. Как уже отмечалось, такие определения легко получить в справочной системе Visual Basic – когда программист тонет, он кричит F1!

Кроме переменных, в программах используются данные, значения которых не изменяются – это константы. Приведем примеры их определения.

Const Pi As Double = 3.14159

Const Nmin As Long = 0

Const Nmax As Long = 999999

Определив константы один раз, например, в начале модуля, ими можно пользоваться во многих инструкциях, не вспоминая каждый раз точное значение числа π. Если же в процессе разработки программы потребуется изменить ограничение Nmax , то это надо будет сделать в единственной инструкции.

Некоторые данные во время работы приложения могут храниться в качестве свойств объектов: свойств ячеек листа Excel, свойств элементов управления и др. Приведем примеры.

Лист2.Cells(2,6).Formula = "=Sum(B1:B5) "

Лист2.Range("A1:D4").Value = Range("A1:D4").Value

TextBox1.Text = "M=" & Str(M) & " N=" & Str(N)

В первом примере свойству Formula объекта Cells(2,6), принадлежащего, в свою очередь, объекту Лист2, присваивается конкретная формула. Этот пример, кстати, показывает, как при программировании на VBA можно пользоваться встроенными в Excel формулами. Но верно и обратное: разрабатывая функции на VBA, можно расширить набор формул, доступных в Excel. Во втором примере значения, хранимые в прямоугольной области ячеек на текущем листе, присваиваются ячейкам одноименной области на листе 2. В третьем примере с помощью операции конкатанации (&) три подстроки объединяются (суммируются) в одну строку, и эта строка присваивается свойству Text объекта TextBox1. Последний пример показывает, как значения M, N вывести в поле, размещенное на форме или на листе Excel.