Алгоритм построения множества Мандельброта

Выполнять для каждой точки выбранного прямоугольника:

1. Записать координаты точки в p и q, обнулить x и y, обнулить счетчик. Перейти к пункту 2.
2. Увеличить счетчик, реализовать преобразования x и y. Перейти к 3.
3. Если модуль числа превысил L или счетчик превысил определенное время Time, остановить преобразования и перейти к 4, иначе перейти к 2.
4. Если счетчик превысил Time, окрасить точку в черный цвет, иначе (модуль превысил L) окрасить точку в цвет тем более темный, чем больше счетчик в момент выхода. Перейти к следующей точке.

Преобразования в пункте 2 имеют вид:

x_t+1 = x_t² – y_t²+p

y_t+1 = 2x_ty_t + q

Модуль комплексного числа z = x + iy вычисляется по формуле: |z|² = x² + y²

Первая задача, с которой вы сталкиваетесь при разработке приложения, – это оформление, создание интерфейса вашей программы.

Начните новый проект, поместите на форму Image кнопку Button, четыре поля ввода Edit, четыре надписи Label и линейку прогресса ProgressBar.

Установите свойства компонентов.

Значения этих полей ввода будут задавать прямоугольную часть комплексной плоскости, которая будет отображаться на компоненте Image.

При кажущейся простоте данного этапа – просто добавить нужные компоненты и расставить их – оформлению нужно уделить надлежащее внимание. Интерфейс должен быть удобным, дружественным пользователю. Он должен быть интуитивно понятным: в идеале пользователь должен догадаться, что куда вводить и на какие кнопки нажимать, без чужой подсказки, не читая учебников и руководства пользователя. Надо стремиться к тому, чтобы для достижения нужного ему эффекта пользователь производил минимум действий – как мышкой, так и с помощью клавиатуры. Если возможно, клавиатурный ввод лучше вообще свести на нет, однако не забыть продублировать все действия горячими клавишами (согласитесь, что для запуска программы в Delphi иногда проще нажать F9, чем целиться мышкой на кнопку в панели инструментов).

Конечно, это идеал, но стремиться к нему нужно. Пользователь всегда чувствует, позаботились ли вы о нем, или слепили форму, особо не утруждаясь, предоставив ему, бедному, мучиться со всеми неудобствами.

Мы реализовали описанный ранее алгоритм построения фрактала Мандельброта:

procedure TForm1.Button1Click(Sender: TObject);
var i, j, t, Time, Size, L: integer;
p0, q0, p1, q1, p, q, x, y, xx: double;
begin
Time := 500;
Size := 250;
L := 100;
p0 := StrToFloat(Edit1.Text);
p1 := StrToFloat(Edit2.Text);
q0 := StrToFloat(Edit3.Text);
q1 := StrToFloat(Edit4.Text);
for i := 0 to Size - 1 do
begin
p := p0 + i * (p1 - p0) / (Size - 1);
for j := 0 toSize - 1 do
begin
q := q0 + j * (q1 - q0) / (Size - 1);
x := 0;
y := 0;
t := 0;
repeat inc(t);
xx := x;
x := sqr(x) - sqr(y) + p;
y := 2 * xx * y + q;
until (x * x + y * y > L) or (t = Time);
if t = TimethenImage1.Canvas.Pixels[i, j] := clNavy
else Image1.Canvas.Pixels[i, j] := RGB(250 - t div 2,
250 - t div 2, 250);
end;
ProgressBar1.Position := round(i * 100 / Size);
end;
end;

При реализации этого алгоритма мы столкнулись с некоторыми новыми для нас функциями. Остановимся подробнее на следующих моментах:

• Функция round служит для перевода чисел с плавающей точкой в целые числа. Делает она это, округляя число до ближайшего целого. Таким образом round(1.4) = 1, a round(8.7) = 9. Мы используем эту функцию для того, чтобы установить свойство Position у полоски прогресса, которое имеет целый тип. Есть и другая функция, переводящая числа с плавающей точкой в целые. Функция trunc округляет до наименьшего целого, то есть trunc(1.4) = 1 и trunc(8.7) = 8.
• функия StrToFloat(const S: string): Extended служит для перевода текстовых строк в действительные числа. Поскольку не всякую строку можно перевести в число, то при вызове этой процедуры нужно быть уверенным, что строка описана верно. Иначе ее вызов приведет к возникновению исключительной ситуации (exception). Об исключительных ситуациях мы поговорим на следующем уроке, пока же, если вдруг возникнет исключительная ситуация, – нажмите Ok и прервите выполнение программы (Ctrl-F2). Обратите внимание, что в строках string десятичная точка должна быть записана в виде запятой: StrToFloat(‘5.5’) вызовет исключительную ситуацию, а StrToFloat(‘5,5’) выдаст число, равное 5.5. Для обратного перевода используется функция FloatToStr(), а для работы с целыми числами используются StrToInt() и IntToStr() соответственно.
• Напоминаем тем, кто работал с Turbo Pascal, что функция inc() увеличивает целое число на единицу, sqr() выдает квадрат действительного числа, а div – это деление целых чисел нацело.
• Введенная нами переменная xx нужна для хранения значения x на прошлом шаге. Если бы ее не было, то y рассчитывался бы с учетом уже измененного x, что некорректно.
• Мы уже знакомы с холстом Canvas, но еще не рассматривали его свойство Pixels[X, Y: Integer]: TColor. В этом доступном для чтения и записи свойстве содержится цвет точки в формате TColor.

Как отмечалось, необходимо заботиться о пользователе, тем более что пока вы сами являетесь единственным пользователем программы. Неплохо бы облегчить навигацию по фракталу. Мышь в этом предоставляет нам богатые возможности.

Увеличивать картинку, задавая каждый раз с клавиатуры четыре числа и нажимая кнопку, не очень удобно. Лучше добиться этого одним нажатием мыши.

Сделаем так, чтобы при нажатии на Image картина увеличивалась в два раза, с центром в точке, на которую мы нажали.

Выделите Image и в Инспекторе Объектов дважды щелкните справа от события OnMouseDown.

В создавшемся обработчике введите код. Здесь мы считываем из полей ввода данные. В зависимости от того, какая кнопка мыши была нажата – левая или правая, мы вычисляем новые границы картинки – увеличенные или уменьшенные.

Эти границы записываем в поля ввода.

Затем вызываем метод Click кнопки Button1. Фактически мы имитируем нажатие на кнопку и, следовательно, вызываем обработчик этого нажатия, перерисовывая картинку.

В результате теперь нам не нужно задавать размеры с клавиатуры, а можно увеличивать и уменьшать картинку, нажимая левую и правую кнопку мыши.

Запустите программу и попробуйте сами.

procedure TForm1.Image1MouseDown(Sender: TObject;
Button: TMouseButton;
Shift: TShiftState;
X, Y: Integer);
var p0, q0, p1, q1, x0, y0, x1, y1: double;
begin
p0 := StrToFloat(Edit1.Text);
p1 := StrToFloat(Edit2.Text);
q0 := StrToFloat(Edit3.Text);
q1 := StrToFloat(Edit4.Text);
if Button = mbLeft then
begin
x0 := p0 + (p1 - p0) * X / Image1.Width - (p1 - p0) / 4;
y0 := q0 + (q1 - q0) * Y / Image1.Height - (q1 - q0) / 4;
x1 := p0 + (p1 - p0) * X / Image1.Width + (p1 - p0) / 4;
y1 := q0 + (q1 - q0) * Y / Image1.Height + (q1 - q0) / 4;
Image1.Repaint;
end
else
begin
x0 := p0 + (p1 - p0) * X / Image1.Width - (p1 - p0);
y0 := q0 + (q1 - q0) * Y / Image1.Height - (q1 - q0);
x1 := p0 + (p1 - p0) * X / Image1.Width + (p1 - p0);
y1 := q0 + (q1 - q0) * Y / Image1.Height + (q1 - q0);
end;
Edit1.Text := FloatToStr(x0);
Edit2.Text := FloatToStr(x1);
Edit3.Text := FloatToStr(y0);
Edit4.Text := FloatToStr(y1);
Button1.Click;
end;