Решение обыкновенных дифференциальных уравнений и систем обыкновенных дифференциальных уравнений

Задание.

1. Решить задачу Коши для уравнения y’ = f ( x, y ).

2. Решить задачу Коши для уравнения y” = f ( x, y, y’ ).

3. Составить кинетическую модель и найти концентрации компонентов данной химической реакции для заданного промежутка времени.

Пример 6. 1.

Найти решение дифференциального уравнения dy / dx = 2y + e ^x - x , удовлетворяющее начальному условию y ( 0 ) = 0,25, на отрезке [ 0; 1 ] , представив результат не менее, чем десятью точками. Решение найти методом Эйлера и методом Рунге-Кутта четвертого порядка. Сравнить полученные результаты с точным решением, имеющим следующий вид: y ( x ) = e ^2x - e ^x + x/2 + 0,25. Построить графики точного и приближенного решений.

Выполнение работы.

Алгоритм метода Эйлера для решения обыкновенного дифференциального уравнения первого порядка y ’ = f (x, y ) на отрезке x Î [ x ₀, x _max ] с начальным условием y ( x ₀ ) = y ₀ задается рекуррентной формулой

y _k+1 = y _k + h* f ( x _k , y _k ) , ( 8 )

где x _k = x ₀ + h*k, k = 0, 1, 2, ... , N - 1 ,

N - число интервалов, на которые разбивается отрезок [ x ₀, x _max ],

h - шаг интегрирования, h = (x _max - x ₀ ) / N .

Алгоритм метода Рунге-Кутта задается рекуррентной формулой

y _k+1 = y _k + ( m ₁ + 2m ₂ + 2m ₃ + m ₄ )*h /6 , ( 9 )

где m ₁ = f ( x _k , y _k ) ,

m ₂ = f (x _k + h/2, y _k + m ₁*h/2 ) ,

m ₃ = f ( x _k + h/2, y _k + m ₂*h/2 ),

m ₄ = f (x _k + h, y _k + m ₃*h ) .

Примем N = 10. Тогда h = 0,1.

1. Введем в первую строку названия столбцов. В столбце А у нас будут находиться значения x; в столбце В - значения y, вычисленные по формуле Эйлера; в столбце С - точные значения y; в столбцах D - G - значения m₁, m₂, m₃, m₄; в столбце H - значения y, вычисленные по методу Рунге-Кутта четвертого порядка.

2. В ячейку I1 введем значение шага “0,1” и присвоим ей имя h. Для этого выделим ячейку I1 и выполним команду Вставка/Имя/Определить. В диалоговом окне Определить имявведем имя “h”.

3. В ячейку A2 введем начальное значение x, т.е. число 0; в ячейки B2, C2, H2 - начальное значение y, т.е. число 0,25.

4. В ячейки A3:H3 введем следующие формулы:

в ячейку A3 =A2+h ;

в ячейку B3 =B2+h*(2*B2+EXP(A2)-A2) ;

в ячейку C3 =EXP(2*A3)-EXP(A3)+A3/2+0,25 ;

в ячейку D3 =2*H2+EXP(A2)-A2 ;

в ячейку E3 =2*(H2+D3*h/2)+EXP(A2+h/2)-A2-h/2 ;

в ячейку F3 =2*(H2+E3*h/2)+EXP(A2+h/2)-A2-h/2 ;

в ячейку G3 =2*(H2+F3*h)+EXP(A2+h)-A2-h ;

в ячейку H3 =H2+(D3+2*E3+2*F3+G3)*h/6.

5. Выделим интервал A3:H3, поставим курсор на маркер заполнения ячейки H3 и распространим формулы, введенные в третью строку, до двенадцатой строки включительно. Полученная таблица ( см. рис. 21 ) содержит искомые приближенные и точное решения.

Рис. 21. Решение уравнения dy/dx = 2y + e^x - x.

6. Как видно из таблицы на рис.21, решение, полученное по методу Рунге-Кутта четвертого порядка, практически совпадает с точным решением. Поэтому графики построим только для точного решения и решения по методу Эйлера ( см. рис. 22).

Рис. 22. Графики точного решения и решения, полученного

по методу Эйлера, для уравнения dy/dx = 2y + e^x - x.

Пример 6.2. k ₁ k ₂

Составить кинетическую модель химической реакции A B C .

Решить методом Эйлера полученную систему дифференциальных уравнений для промежутка времени t = [ 0; 3 ] с шагом 0,2, если начальные концентрации компонентов С_A ( 0 ) = 1, C_B (0 ) = C_C (0 ) = 0, константы скоростей k ₁ = 0,6; k ₂ =0,8. Построить графики кинетических кривых.

Выполнение работы.

Кинетическая модель данной химической реакции представляется следующей системой уравнений [ 10 ]:

dC_A / dt = - k ₁ * C_A

dC_B / dt = k ₁ * C_A - k ₂ * C_B

dC_C / dt = k ₂ * C_B

1. Введем в первую строку названия столбцов. В столбце А у нас будут находиться значения времени, в столбцах B, C, D - значения концентраций компонентов A, B, C, соответственно.

2. В ячейку Е1 введем значение шага “0,2” и присвоим ей имя h.

3. Введем в ячейки A2:D2 начальные значения времени и концентраций компонентов реакции.

4. В ячейки A3:D3 введем следующие формулы:

в ячейку А3 =A2+h;

в ячейку В3 =$B2+h*(-0,6*$B2);

в ячейку С3 =$C2+h*(0,6*$B2-0,8*$C2);

в ячейку D3 =$D2+h*(0,8*$C2)

5. Выделим интервал A3:D3 и распространим формулы, введенные в третью строку, до семнадцатой строки включительно.

6. Построим диаграмму типа График, в которой, используя блок ячеек A1:D17, отобразим зависимости концентраций компонентов реакции от времени. Отформатируем диаграмму.

Результирующая таблица и графики кинетических кривых приведены на рис.23.

Рис. 23. Исследование кинетики химической реакции.